<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:kso="nothin">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="h1 h2 body" />

<xsl:variable name="Copyright">Copyright &#169; 2006 Example1 Co, Inc. All Rights Reserved</xsl:variable>

<xsl:variable name="ChapterTitle">Plays by the Bard</xsl:variable>


<xsl:template match="/">
	<fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
		<fo:layout-master-set>
			<fo:simple-page-master
				master-name="first"
				margin-right="0.25in"	margin-left="0.25in"
				margin-bottom="0.25in"	margin-top="0.25in"
				page-width="8.5in" 		page-height="11in"
			>
				<fo:region-before extent="0.5in" region-name="first-before" />
				<fo:region-after extent="0.5in" region-name="first-after" />
				<fo:region-start extent="0.5in" />
				<fo:region-end extent="0.5in" />
				<fo:region-body 	margin-top="1.0in"	margin-bottom="1.0in"
								margin-left="0.5in"	margin-right="0.5in" 
				/>
			</fo:simple-page-master>
			
			<fo:simple-page-master
				master-name="odd"
				margin-right="0.25in"	margin-left="0.25in"
				margin-bottom="0.25in"	margin-top="0.25in"
				page-width="8.5in" 		page-height="11in"
			>
				<fo:region-before extent="0.5in" region-name="odd-before"/>
				<fo:region-after extent="0.5in" region-name="odd-after"/>
				<fo:region-start extent="0.5in" />
				<fo:region-end extent="0.5in" />
				<fo:region-body 	margin-top="1.0in"	margin-bottom="1.0in"
								margin-left="0.5in"	margin-right="0.5in" 
				/>
			</fo:simple-page-master>

			<fo:simple-page-master
				master-name="even"
				margin-right="0.25in"	margin-left="0.25in"
				margin-bottom="0.25in"	margin-top="0.25in"
				page-width="8.5in" 		page-height="11in"
			>
				<fo:region-before extent="0.5in" region-name="even-before" />
				<fo:region-after extent="0.5in" region-name="even-after" />
				<fo:region-start extent="0.5in" />
				<fo:region-end extent="0.5in" />
				<fo:region-body 	margin-top="1.0in"	margin-bottom="1.0in"
								margin-left="0.5in"	margin-right="0.5in" 
				/>
			</fo:simple-page-master>

			<fo:simple-page-master
				master-name="blank"
				margin-right="0.25in"	margin-left="0.25in"
				margin-bottom="0.25in"	margin-top="0.25in"
				page-width="8.5in" 		page-height="11in"
			>
				<fo:region-before extent="0.5in" region-name="blank-before"/>
				<fo:region-after extent="0.5in" region-name="blank-after" />
				<fo:region-start extent="0.5in" />
				<fo:region-end extent="0.5in" />
				<fo:region-body 	margin-top="1.0in"	margin-bottom="1.0in"
								margin-left="0.5in"	margin-right="0.5in" 
				/>
			</fo:simple-page-master>
			
			<fo:page-sequence-master master-name="chapter">
				<fo:repeatable-page-master-alternatives>
					<fo:conditional-page-master-reference
						master-reference="first"
						page-position="first"
					/>

					<fo:conditional-page-master-reference
						master-reference="odd"
						page-position="rest"
						odd-or-even="odd"
					/>

					<fo:conditional-page-master-reference
						master-reference="even"
						page-position="rest"
						odd-or-even="even"
					/>

					<fo:conditional-page-master-reference
						master-reference="blank"
						blank-or-not-blank="blank"
					/>
				</fo:repeatable-page-master-alternatives>
			</fo:page-sequence-master>
		</fo:layout-master-set>
		<fo:page-sequence 	master-reference="chapter"
							initial-page-number="auto"
							force-page-count="even"
		>
			<fo:static-content flow-name="odd-before">
				<fo:block text-align="right" font-family="Helvectica, Arial, sans-serif" font-size="10pt">
					<xsl:value-of select="$ChapterTitle" />
				</fo:block>
			</fo:static-content>
			<fo:static-content flow-name="odd-after">
				<fo:block text-align="right">
					Page <fo:page-number />
				</fo:block>
				<fo:block text-align="center" font-family="Helvectica, Arial, sans-serif" font-size="8pt">
					<xsl:value-of select="$Copyright" />
				</fo:block>
			</fo:static-content>
			<fo:static-content flow-name="even-before">
				<fo:block text-align="left" font-family="Helvectica, Arial, sans-serif" font-size="10pt">
					<xsl:value-of select="$ChapterTitle" />
				</fo:block>
			</fo:static-content>
			<fo:static-content flow-name="even-after">
				<fo:block text-align="left">
					Page <fo:page-number />
				</fo:block>
				<fo:block text-align="center" font-family="Helvectica, Arial, sans-serif" font-size="8pt">
					<xsl:value-of select="$Copyright" />
				</fo:block>
			</fo:static-content>

			<fo:static-content flow-name="first-before">
			</fo:static-content>

			<fo:static-content flow-name="first-after">
				<fo:block text-align="right">
					Page <fo:page-number />
				</fo:block>
				<fo:block text-align="center" font-family="Helvectica, Arial, sans-serif" font-size="8pt">
					<xsl:value-of select="$Copyright" />
				</fo:block>
			</fo:static-content>

			<fo:static-content flow-name="blank-before">
			</fo:static-content>

			<fo:static-content flow-name="blank-after">
				<fo:block text-align="right">
					Page <fo:page-number />
				</fo:block>
				<fo:block text-align="center" font-family="Helvectica, Arial, sans-serif" font-size="8pt">
					<xsl:value-of select="$Copyright" />
				</fo:block>
			</fo:static-content>
			
			<!-- Content flow starts here -->
			<fo:flow flow-name="xsl-region-body">
				<xsl:apply-templates />
			</fo:flow>
		</fo:page-sequence>
	</fo:root>
</xsl:template>

<!-- Templates -->
<xsl:template match="PLAY">
	<fo:block font-family="Helvectica, Arial, sans-serif" font-size="32pt" space-before="20pt" space-after="8pt"><xsl:value-of select="TITLE"/></fo:block>
	<xsl:apply-templates select="ACT" />
</xsl:template>

<xsl:template match="ACT">
	<fo:block font-family="Helvectica, Arial, sans-serif" font-size="24pt" space-before="20pt" space-after="8pt"><xsl:value-of select="TITLE"/></fo:block>
	<xsl:apply-templates select="SCENE" />
</xsl:template>

<xsl:template match="SCENE">
	<fo:block font-family="Helvectica, Arial, sans-serif" font-size="18pt" space-before="20pt" space-after="8pt"><xsl:value-of select="TITLE"/></fo:block>
	<xsl:apply-templates select="SPEECH" />
</xsl:template>

<xsl:template match="SPEECH">
 	<fo:block font-family="Helvectica, Arial, sans-serif" font-size="12pt" space-before="16pt" space-after="8pt" font-weight="bold">
		<xsl:value-of select="SPEAKER" />
	</fo:block>
	<xsl:apply-templates select="LINE" />
</xsl:template>
	
<xsl:template match="LINE">
 	<fo:block font-family="Helvectica, Arial, sans-serif" font-size="12pt" space-after="4pt">
		<xsl:value-of select="." />
	</fo:block>
</xsl:template>


</xsl:stylesheet>